Large Peak Commit Charge at Startup

Status
This thread has been Locked and is not open to further replies. Please start a New Thread if you're having a similar issue. View our Welcome Guide to learn how to use this site.

Renak

Thread Starter
Joined
May 16, 2010
Messages
2
Greetings All,

Hope this is the correct forum. I just recently purchased an off lease HP NC6230 laptop pre-loaded with XP Pro SP 2. The laptop boots ridiculously fast and all programs operate flawlessly. My question is more out of curiosity than anything else as I don't have any issues...yet. I want to make sure I don't have a possible future issue that will cause me to have to reinstall XP or do something else and thereby lose all the programs I'm about to download/install.

Only because I recently added memory to my other HP laptop and my older Dell Dimension desktop am I now more familiar with Task Manager. So the first thing I did after booting up the NC6230 was check the task manager. I have 2 GB RAM and my concern is that the Peak Commit Charge right after startup is at 1.8 GB. My other HP laptop has 2 GB and, even after using programs all day, maybe hits 1.2GB. Same with the Dell.

It's not causing a problem but I can't figure out what's loading. There's barely anything running in the process list - the program totals don't come close to the peak charge. I did the usual cleanup in MSCONFIG startup but there's nothing there really. I then did a safe mode boot up and the peak was around 400K so there's definitely something loading or causing this "spike" during regular boot.

I've read tons of threads about similar issues but not where the safe mode is so much less. I wouldn't even sweat it but my other PCs are running tons of programs and not even close to the physical memory.

If it matters, the virtual memory is set to 3070 and 4000. My available physical memory at startup is right around the same as the Peak charge...1.79GB - 1.80GB. I also took out the extra 1GB chip [leaving 1GB total] to see what would happen. The peak in that case was around 790K right after startup - still about 80% of physical. Like I said, it's not causing a problem but how can I find out why the peak is so large at startup? Any suggestions?

Thanks for your input...really appreciate it.
Walt
 

Renak

Thread Starter
Joined
May 16, 2010
Messages
2
Thanks for the quick reply. So that means that the peak # I'm seeing isn't representing 1.7-1.8 GB of my actual RAM in use since the last reboot but maybe virtual memory and/or page file? This stuff is way over my head. I just want to make sure that I'm not headed for a blue screen with the O/S set up this way. That's why I thought of a reformat and reinstall. That's almost all I know how to do :). I still don't understand what is making the peak # so large just by turning the laptop on. Is there a way to trace what happens during startup? I've read about 'memory leaks' and still don't know what they are. I thought maybe that's what this was. Should I just not worry about it since the available memory is around 1.7 GB and that's more important?
 
Joined
Aug 7, 2007
Messages
9,028
In Task Manager, select the Processes tab. Click View | Select Columns...
Check Peak Memory Usage and Virtual Memory Size.

This might let you see what process is allocating all that memory at boot. You can sort by those columns.

Is the page file set this large on the other systems? Could be a program is seeing the large pagefile, so is allocating a larger chunk of Virtual Memory than it would with a smaller page file.

You can use this script to see how much of the page file you are actually using.

If you want to monitor your actual page file usage, you can use this script. I'd recommend setting it up as a logoff script (instructions in the script comments) so the peak usage is recorded each time you logoff. You may find it rarely goes above 100-200 MB.
Works on Vista and Win 7 as well.
Save it as PageFile.vbs and double click to run. Info on configuration is in the beginning of the file.
Code:
' WinXP-2K_PageFile.vbs - Checks the current and peak usage, and allocated
' size of the Windows Windows XP or Windows 2000 pagefile and optionally
' log and/or show the results in a popup.
' © Bill James - [email protected] - Created 4 Nov 2002 - Revised 10 Nov 2002
' Please see the ReadMe.txt file for additional information.

' You can run this script manually during a Windows session, or if you have
' Windows XP/2000 Pro I recommend adding it as a logoff script to log results
' at the end of each Windows session.  To implement running the script at
' logoff (also shutdown and restart) for Windows XP Pro or Windows 2000 Pro:
' Click Start, Run, gpedit.msc.  Select User Configuration, Windows Settings,
' Scripts.  In the right pane, select Logoff, Properties.  Click Add, Browse.
' Browse to the location of this script and select it.  IMPORTANT: In the
' "Script Parameters" box add "log" (no quotes) so the script will not show a
' popup which would stall your shutdown sequence.  OK, Apply, OK.  (You may
' want to first copy this script to the logoff folder and select it there)

' If logging is enabled (default), the results are saved in My Documents folder
' as PageFileLog.txt.

'**********************************************************
' Three optional settings are configurable below:
'  WriteToFile - If set to True the information will be added to a log file in
'    your 'My Documents' folder.  Of course, you want this if you are running
'    at logoff, but you might not want it for manually checks.  Changing this
'    to False disables logging.
'   ShowPopup - If set to True then after the script runs a message box is
'     presented with the results.  This might not be desirable when
'     automatically running the script at logoff.  False disables popup.
'   DisplaySeconds - The number of seconds that the results popup will
'     display.  Setting this to 0 (zero) will cause the popup to remain until
'     acknowledged.

WriteToFile = True    'Options: True, False
ShowPopup = True      'Options: True, False
DisplaySeconds = 0    '0 (zero) to force OK
'**********************************************************

'**********************************************************
' You can also set the options using arguments:
' Syntax:  [path]scriptname [log] [rpt] [t:sec]
'   log - add results to the logfile
'   rpt - show results in popup
'   t:seconds - controls how long the popup message will display

' Example: "WinXP-2K_PageFile.vbs rpt t:5" - show popup for 5 seconds, no log.
' Example: "WinXP-2K_PageFile.vbs log" - log the results, no popup.
' Example: "WinXP-2K_PageFile.vbs log rpt t:10" - log and 10 second popup.

' NOTE: If ANY arguments are used, all hardcoded variables are set to
' false or 0, so you must specifically set which options you want.

' To use these options, create a shortcut to the script and add the arguments
' there, or the arguments can be used running the script from command line.
'**********************************************************

' Do not edit below this line
If WScript.Arguments.Count > 0 Then
  WriteToFile = False
  ShowPopup = False
  DisplaySeconds = 0
  For Each arg in WScript.Arguments
    If LCase(arg) = "log" Then
      WriteToFile = True
    End If
    If LCase(arg) = "rpt" Then
      ShowPopup = True
    End If
    If Left(LCase(arg), 2) = "t:" Then
      If IsNumeric(Mid(arg, 3)) Then
        DisplaySeconds = Mid(arg, 3)
      End If
    End If
  Next
End If

For Each obj in GetObject("winmgmts:\\.\root\cimv2").ExecQuery(_
    "Select Name, CurrentUsage, PeakUsage, " & _
    "AllocatedBaseSize from Win32_PageFileUsage",,48)
  s = s & vbcrlf & "Pagefile Physical Location: " & vbtab & obj.Name
  s = s & vbcrlf & "Current Pagefile Usage: " & vbtab & obj.CurrentUsage & " MB"
  s = s & vbcrlf & "Session Peak Usage: " & vbtab & obj.PeakUsage & " MB"
  s = s & vbcrlf & "Current Pagefile Size: " & vbtab & obj.AllocatedBaseSize & " MB"
Next

If WriteToFile Then
  Set fso = CreateObject("Scripting.FileSystemObject")
  logfile = CreateObject("WScript.Shell"). _
    SpecialFolders("MyDocuments") & "\PagefileLog.txt"
  If NOT fso.OpenTextFile(logfile, 1, True).AtEndOfStream Then
    With fso.OpenTextFile(logfile, 1)
      s2 = .ReadAll : .Close
    End With
  End If
  With fso.OpenTextFile(logfile, 2)
    .Write Now() & vbcrlf & s & vbcrlf & vbcrlf & s2 : .Close
  End With
End If

If ShowPopup Then
  WScript.CreateObject("WScript.Shell").Popup _
    s, DisplaySeconds, "WinXP Pagefile Usage Monitor by Bill James", 4096
End If

' Revison History
' 9 Nov 2002 - Various prerelease changes
' 10 Nov 2002 - Tweaked to show stats where multiple drives have a pagefile
 
Status
This thread has been Locked and is not open to further replies. Please start a New Thread if you're having a similar issue. View our Welcome Guide to learn how to use this site.

Users Who Are Viewing This Thread (Users: 0, Guests: 1)

As Seen On
As Seen On...

Welcome to Tech Support Guy!

Are you looking for the solution to your computer problem? Join our site today to ask your question. This site is completely free -- paid for by advertisers and donations.

If you're not already familiar with forums, watch our Welcome Guide to get started.

Join over 807,865 other people just like you!

Latest posts

Members online

Top